Ошибка при обновлении списка текущих дел в КА/ERP 2.5.12

При открытии программы в списке текущих дел появляется ошибка:

Ошибка при вызове метода контекста (ВыполнитьПакет)
{РегистрСведений.ЗастрахованныеЛицаСЭДО.МодульМенеджера(508)}:Пакет = Запрос.ВыполнитьПакет();

Ошибка связана с тем, что для РегистрСведений.ЗастрахованныеЛицаСЭДО включена RLS, но предопределенный элемент для регистра в справочнике Справочник.ИдентификаторыОбъектовМетаданных отсутствует.

Временно обходится заимствованием функции ТребованияПоОтправке модуля менеджера регистра сведений ЗастрахованныеЛицаСЭДО.

&ИзменениеИКонтроль("ТребованияПоОтправке")
Функция ВИ_ТребованияПоОтправке()
	НачалоТекущегоДня  = НачалоДня(ТекущаяДатаСеанса());
	НачалоРабочегоДня  = НачалоДня(СЭДОФСС.БлижайшийРабочийДень(НачалоТекущегоДня));
 
	Запрос = Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ РАЗРЕШЕННЫЕ
	|	СУММА(ВЫБОР
	|			КОГДА ЗастрахованныеЛицаСЭДО.ВРаботе
	|				ТОГДА 1
	|			ИНАЧЕ 0
	|		КОНЕЦ) КАК КоличествоВРаботе,
	|	СУММА(ВЫБОР
	|			КОГДА ЗастрахованныеЛицаСЭДО.КОтправке
	|				ТОГДА 1
	|			ИНАЧЕ 0
	|		КОНЕЦ) КАК КоличествоКОтправке,
	|	СУММА(ВЫБОР
	|			КОГДА ЗастрахованныеЛицаСЭДО.НаОформлении
	|				ТОГДА 1
	|			ИНАЧЕ 0
	|		КОНЕЦ) КАК КоличествоНаОформлении,
	|	СУММА(ВЫБОР
	|			КОГДА ЗастрахованныеЛицаСЭДО.МаксимальнаяДатаОтправки <= &НачалоРабочегоДня
	|				ТОГДА 1
	|			ИНАЧЕ 0
	|		КОНЕЦ) КАК КоличествоСегодня,
	|	СУММА(ВЫБОР
	|			КОГДА ЗастрахованныеЛицаСЭДО.КОтправке
	|					И ЗастрахованныеЛицаСЭДО.МаксимальнаяДатаОтправки <= &НачалоРабочегоДня
	|				ТОГДА 1
	|			ИНАЧЕ 0
	|		КОНЕЦ) КАК КоличествоКОтправкеСегодня,
	|	СУММА(ВЫБОР
	|			КОГДА ЗастрахованныеЛицаСЭДО.НаОформлении
	|					И ЗастрахованныеЛицаСЭДО.МаксимальнаяДатаОтправки <= &НачалоРабочегоДня
	|				ТОГДА 1
	|			ИНАЧЕ 0
	|		КОНЕЦ) КАК КоличествоНаОформленииСегодня
	|ИЗ
	|	РегистрСведений.ЗастрахованныеЛицаСЭДО КАК ЗастрахованныеЛицаСЭДО
	|ГДЕ
	|	ЗастрахованныеЛицаСЭДО.ВРаботе
	|	И НЕ ЗастрахованныеЛицаСЭДО.Скрыть";
	Запрос.УстановитьПараметр("НачалоРабочегоДня", НачалоРабочегоДня);
 
#Удаление
	Пакет = Запрос.ВыполнитьПакет();
#КонецУдаления
#Вставка
// Здесь можно описать новое поведение.
	УстановитьПривилегированныйРежим(Истина);
	Пакет = Запрос.ВыполнитьПакет();
	УстановитьПривилегированныйРежим(Ложь);
#КонецВставки
	Таблица = Пакет[0].Выгрузить();
 
	Результат = Новый Структура;
	Для Каждого Колонка Из Таблица.Колонки Цикл
		Результат.Вставить(Колонка.Имя, 0);
	КонецЦикла;
	Если Таблица.Количество() > 0 Тогда
		СтрокаТаблицы = Таблица[0];
		Если СтрокаТаблицы.КоличествоВРаботе <> Null Тогда
			ЗаполнитьЗначенияСвойств(Результат, СтрокаТаблицы);
		КонецЕсли;
	КонецЕсли;
 
	Возврат Результат;
КонецФункции